VERGLEICH - Vergleich

REXX Überblick
REXX Konventionen

Syntax:                                 
NICHT (deu ^ = eng \)
Gleich                       =      ^=   /=   <>   ><
Groeßer                      >      ^>
Kleiner                      <      ^<
Groeßer oder gleich          >=     ^>=
Kleiner oder gleich          <=     ^<=
Identisch                    ==     ^==   /==
Streng groeßer               >>     ^>>
Streng kleiner               <<     ^<<
Streng groeßer oder gleich   >>=
Streng kleiner oder gleich   <<=

Und                          &
Oder                         !
Exclusiv oder                &&
Logisches "nicht"            ^

/* REXX VERGLEICH Copyright YCOS Yves Colliard Software 1990-2009 */
/* TRACE ?R  */
  /* einschalten des interaktiven Trace Modus */
  /* */
a1 = "REXX "
a2 = "Yves Colliard Software"
b1 = 10.0
b2 = 123
  /* */
IF a1 = "REXX" THEN           /* Gleich                      */
   SAY "Kond1 wahr"           /* Ausgabe: Kond1 wahr         */
ELSE
   SAY "Kond1 unwahr"
  /* */
IF a1 == "REXX" THEN          /* Identisch                   */
   SAY "Kond2 wahr"
ELSE
   SAY "Kond2 unwahr"         /* Ausgabe: Kond2 unwahr       */
  /* */
IF b1 <> 10 THEN              /* Ungleich                    */
   SAY "Kond3 wahr"
ELSE
   SAY "Kond3 unwahr"         /* Ausgabe: Kond3 unwahr       */
  /* */
IF b1 < b2 & a1 = "  REXX" THEN
/*  wahr   &    wahr  */
   SAY "Kond4 wahr"           /* Ausgabe: Kond4 wahr         */
ELSE
   SAY "Kond4 unwahr"
  /* */
IF (b1 < b2 & a1 == "REXX") ! b2 <> "Bonjour"  THEN
/* ( wahr   &   unwahr    )oder     wahr    */
/* (     unwahr           )oder     wahr    */
/*                         wahr             */
   SAY "Kond5 wahr"           /* Ausgabe: Kond5 wahr         */
ELSE
   SAY "Kond5 unwahr"
  /* Groesser */
IF 077 > 11 THEN SAY "Kond6 wahr"   /* Ausgabe: Kond6 wahr   */
ELSE SAY "Kond6 unwahr"
  /* Streng Groesser */
IF 077 >> 11 THEN SAY "Kond7 wahr"
ELSE SAY "Kond7 unwahr"             /* Ausgabe: Kond7 unwahr */