/* REXX YUSSALLO Copyright YCOS Yves Colliard Software 1990-2009 */
/* TRACE ?R  */
  /* einschalten des interaktiven Trace Modus */
  /* */
/***  REXX  **********************************************************/
/*  Funktion:  Allocate a USS File and write it - and read it        */
/*********************************************************************/
resp=MSG('OFF')
"free fi(om)"
"ALLOC FI(OM) PATH('/tmp/rexx.test')",
   "PATHOPTS(OWRONLY,OCREAT)",
   "PATHDISP(KEEP,KEEP)",
   "PATHMODE(SIRWXU)",
   "FILEDATA(TEXT)"
/* PATHOPTS(access,status)                                     */
/* access: OWRONLY ORDONLY ORDWR                               */
/*         write   read    read/write                          */
/* status: OAPPEND OCREAT OEXCL ONOCTTY ONONBLOCK OSYNC OTRUNC */
/*                        does no exist                        */
/* PATHDISP(norm,abnorm)                                       */
/* disposition: KEEP DELETE                                    */
/* PATHMODE(fileattr)                                          */
/* file owner attribute SIxzzz or SIyyya                       */
/*   x = Read Write eXecute                                    */
/*   zzz = USeR GRouP OTHer                                    */
/*   yyy = RWX                                                 */
/*   a = User Group Other                                      */
/*   x = Set                                                   */
/*   zzz = UID GID                                             */
/*   SIRUSR SIWUSR SIXUSR SIRWXU SIRGRP SIWGRP SIXGRP          */
/*   SIRWXG SIROTH SIWOTH SIXOTH SIRWXO SISUID SISGID          */
a.1="Das ist ein Test"
a.2="YCOS Yves Colliard Software GmbH"
"execio 2 diskw om (stem a. finis"
"free fi(om)"
/* Read it again!! */
"ALLOC FI(OM) PATH('/tmp/rexx.test')",
   "PATHOPTS(ORDONLY)",
   "PATHDISP(KEEP,KEEP)",
   "FILEDATA(TEXT)"
"execio * diskr om (stem b. finis"
do i=1 to b.0
say strip(b.i)
end
"free fi(om)"
resp=MSG(resp)