SCHABLONE - Schablone PARSE

Allgemein

Beispiel:                                 

/* REXX SCHABLO Copyright YCOS Yves Colliard Software 1990-2009 */
/* TRACE ?R  */
  /* einschalten des interaktiven Trace Modus */
  /* */
/* a - Wort Schablone */
PARSE VALUE "rexx tsoispf kurs" WITH infa infb infc
SAY "infa =" infa                    /* infa = rexx            */
SAY "infb =" infb                    /* infb = tsoispf         */
SAY "infc =" infc                    /* infc = kurs            */
/* */
PARSE VALUE "rexx tsoispf kurs" WITH infa infb
SAY "infa =" infa                    /* infa = rexx            */
SAY "infb =" infb                    /* infb = tsoispf kurs    */
/* */
PARSE VALUE "rexx tsoispf kurs" WITH infa . infc
SAY "infa =" infa                    /* infa = rexx            */
SAY "infc =" infc                    /* infc = kurs            */
/* */
/* b - Text Schablone */
PARSE VALUE "rexx tsoispf kurs" WITH "ex" infa infb infc
SAY "infa =" infa                    /* infa = x               */
SAY "infb =" infb                    /* infb = tsoispf         */
SAY "infc =" infc                    /* infc = kurs            */
/* */
PARSE VALUE "rexx/tsoispf/kurs" WITH "/" infb "/" infc
SAY "infb =" infb                    /* infb = tsoispf         */
SAY "infc =" infc                    /* infc = kurs            */
/* */
/* c - Spalten Schablone */
PARSE VALUE "rexx tsoispf kurs" WITH 6 infb 13
SAY "infb =" infb                    /* infb = tsoispf         */
/* */
PARSE VALUE "rexx tsoispf kurs" WITH 2 infa 4 7 infb 12 15 infc 17
SAY "infa =" infa                    /* infa = ex              */
SAY "infb =" infb                    /* infb = soisp           */
SAY "infc =" infc                    /* infc = ur              */
/* */
/* d - Relative Schablone */
PARSE VALUE "rexx tsoispf kurs" WITH infa +8 infc
SAY "infa =" infa                    /* infa = rexx tso        */
SAY "infc =" infc                    /* infc = ispf kurs       */
PARSE VALUE "rexx/tsoispf/kurs" WITH "/" -2 infb +13 -2 infc
SAY "infb =" infb                    /* infb = xx/tsoispf/ku   */
SAY "infc =" infc                    /* infc = kurs            */
/* */
/* e - Variable-Inhalt Schablone */
vamust = " tso"
PARSE VALUE "rexx tsoispf kurs" WITH infa (vamust) infc
SAY "infa =" infa                    /* infa = rexx            */
SAY "infc =" infc                    /* infc = ispf kurs       */
/* */