PARSE - Bearbeitung der Zeichenkette

REXX Instruktionen

Syntax:                                 
PARSE  <UPPER> ARG           <Schablone>
ARG same as PARSE UPPER ARG
PARSE  <UPPER> EXTERNAL      <Schablone>
PARSE  <UPPER> NUMERIC       <Schablone>
PARSE  <UPPER> PULL          <Schablone>
PULL same as PARSE UPPER PULL
PARSE  <UPPER> SOURCE        <Schablone>
PARSE  <UPPER> VALUE <Variable>
WITH       <Schablone>
PARSE  <UPPER> VAR Variable  <Schablone>
PARSE  <UPPER> VERSION       <Schablone>

/* REXX PARSE Copyright YCOS Yves Colliard Software 1990-2009 */
/* TRACE ?R  */
  /* einschalten des interaktiven Trace Modus */
  /* */
a = "Yves Colliard Software"
b = "24.01.07"
  /* */
/* * Die Prozedur wurde mit folgenden Parametern aufgerufen:   */
           /* VORNAME NAME FIRMA                               */
PARSE UPPER ARG vor nam fir
           /* diese Instruktion koennte man auch so schreiben: */
           /* ARG vor nam fir rest                             */
SAY "Vorn." vor "Name" nam "Firma" fir
           /* Ausgabe: Vorn. XXX Name XXX Firma XXX            */
  /* */
/* * Bearbeitungsdatum wird vom Operator verlangt: tt/mm/jj    */
SAY "Bitte Datum eingeben: TT/MM/JJ"
PARSE EXTERNAL tag "/" mon "/" jahr
           /* in NETVIEW muss diese Abfrage mit:               */
           /* GO tt/mm/jj beantwortet werden                   */
SAY "Tag" tag "Monat" mon "Jahr" jahr
           /* Ausgabe: Tag tt Monat mm Jahr jj                 */
/* * Ueberprufung der numerischen Darstellung                  */
PARSE NUMERIC dig fzz frm
SAY "Digits" dig "Fuzz" fzz "Form" frm
           /* Ausgabe: Digits 9 Fuzz 0 Form SCIENTIFIC         */
  /* */
/* * Einlesen eines Program-Stack Eintrags                     */
QUEUE a           /* a wird in den Program-Stack gestellt      */
PARSE UPPER PULL vorn name firma
           /* diese Instruktion koennte man auch so schreiben: */
           /* PULL vorn name firma                             */
SAY vorn name firma
           /* Ausgabe: YVES COLLIARD SOFTWARE                  */
  /* */
/* * Prozedur Beschreibung                                     */
PARSE SOURCE alltxt
SAY alltxt
           /* Ausgabe: TSO COMMAND YPARSE SYSPROC ? ? TSO ISPF */
  /* */
/* * Bearbeitung einer Information                             */
PARSE VALUE "REXX" a b WITH "EX" infa "." mon "."
SAY infa mon
           /* Ausgabe: X Yves Colliard Software mm tt          */
  /* */
/* * Bearbeitung einer Variable                                */
PARSE VAR b tag +2 +1 mon +2 +1 jahr
SAY "Tag" tag "Monat" mon "Jahr" jahr
           /* Ausgabe: Tag tt Monat mm Jahr jj                 */
  /* */
/* * REXX Version                                              */
PARSE VERSION rxnam rxver rxdat
SAY "REXX" rxnam "V." rxver "Datum" rxdat
           /* Ausgabe: REXX REXX370 V. 3.48 Datum 01 May 1992  */
  /* */