DO END - Schleifen (und Bedingungen)

REXX Instruktionen

Syntax:                                 
DO  Instruktion END

DO Nummer
Instruktion END

DO Variable = Anfang   <TO Ende>
<BY Schritt>    <FOR Maximum>
Instruktion END

DO FOREVER
Instruktion END

DO UNTIL   Kondition
Instruktion END

DO WHILE   Kondition
Instruktion END

/* REXX DOEND Copyright YCOS Yves Colliard Software 1990-2009 */
/* TRACE ?R  */
  /* einschalten des interaktiven Trace Modus */
  /* */
a = 'HEUTE'
b = 'MORGEN'
c = 25
d = 10
f = 'HEU'
g.1 = 'REXX'
g.2 = 'TSOISPF'
g.3 = 'KURS'
  /* */
IF a <> b THEN DO    /* die Instruktionen werden einmal ausgefuehrt */
  SAY 'ja'           /* Ausgabe: ja   */
  c = c + 1
  SAY c              /* Ausgabe: 26   */
END
  /* */
DO 5                 /* 5malige Ausfuehrung         */
  SAY 'ja'           /* Ausgabe: ja, ja, ja, ja, ja */
END
  /* */
DO i=1 TO 3          /* 3malige Ausfuehrung, von 1 bis 3 */
  SAY g.i            /* Ausgabe: REXX, TSOISPF, KURS    */
END
  /* */
DO k=20 TO 5 BY -5   /* 4malige Ausfuehrung, von 20 bis 5 um -5 */
  SAY k              /* Ausgabe: 20, 15, 10 und 5               */
END
  /* */
DO UNTIL d=c         /* bis d = c                        */
  d = d + 1          /* Ausgabe: 11, 12, 13, 14, 15, ... */
  SAY d              /* ..., 23, 24, 25 und 26           */
END
  /* */
DO WHILE d>23        /* solange d groesser als 23 */
  d = d - 1          /* Ausgabe: 25, 24 und 23   */
  SAY d
END
  /* */
DO FOREVER           /* fuer immer ... */
  SAY 'TOUJOURS'     /* Ausgabe: TOUJOURS, TOUJOURS, ... */
END                  /* Abbruch mit PA1                  */
  /* */