DATE - Datum abfragen/umsetzen

REXX Built-In Funktionen
Allgemeine Funktionen

Syntax:                                 
DATE(<"N"/B"/"C"/"D"/"E"/"J"/"M"/"O"/"S"/"U"/"W">)
DATE(<outform>,inpdate<,inpform>)
Normal Datum im Format: tt mon jjjj
Basedate Anzahl Tage seit dem 1. Januar 0001
Century Anzahl Tage seit dem 1. Januar 1900
Days Anzahl Tage seit dem 1. Januar dieses Jahres
European Datum nach euro. Format: TT/MM/JJ
Julian Datum im Format: JJTTT
Month englischer Name des aktuellen Monats: "January"...
Ordered Datum im Format: JJ/MM/TT
Sorted Datum im Format: JJJJMMTT
Usa Datum im Format: MM/TT/JJ
Weekday englischer Name des aktuellen Wochentags: "Monday"...

/* REXX DATE Copyright YCOS Yves Colliard Software 1990-2009 */
/* TRACE ?R  */
  /* einschalten des interaktiven Trace Modus */
  /* */
  /* */
SAY DATE()                        /* Ausgabe: 26 Mar 2008     */
SAY DATE('B')                     /* Ausgabe: 733126          */
SAY DATE('B')//7                  /* Ausgabe: 0   -> Montag   */
                                  /* Ausgabe: 1   -> Dienstag */
                                  /* Ausgabe: 2   -> Mittwoch */
                                  /* Ausgabe: 6   -> Sonntag  */
SAY DATE('C')                     /* Ausgabe: 3008            */
SAY DATE('D')                     /* Ausgabe: 86              */
SAY DATE('E')                     /* Ausgabe: 26/03/08        */
SAY DATE('J')                     /* Ausgabe: 08086           */
SAY DATE('M')                     /* Ausgabe: March           */
SAY DATE('N')                     /* Ausgabe: 26 Mar 2008     */
SAY DATE('O')                     /* Ausgabe: 08/03/26        */
SAY DATE('S')                     /* Ausgabe: 20080326        */
SAY DATE('U')                     /* Ausgabe: 03/26/08        */
SAY DATE('W')                     /* Ausgabe: Wednesday       */
  /* */
/*------------------------------------------------------------*/
  /* */
datum="24/01/07"                  /* Eingabe Datum            */
t.0="Montag"
t.1="Dienstag"
t.2="Mittwoch"
t.3="Donnerstag"
t.4="Freitag"
t.5="Samstag"
t.6="Sonntag"
  /* */
temp=date("B",datum,"E")//7
say datum "war ein" t.temp        /* Wochentag                */
  /* */
say "Anzahl Tagen:" date("B")-date("B",datum,"E")
say "-----------------"
  /* */
/*------------------------------------------------------------*/
  /* */
datum="07024"                     /* Datum Julian umrechnen   */
  /* */
temp=date("B","01/01/"left(datum,2),"E")+right(datum,3)
say "Anzahl Tagen:" date("B")-temp+1
say "Heute " date("E") "-" date("J")
say "Damals" date("E",temp-1,"B") "-" datum
exit